home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d5 / trucker.arc / TRUCKER.BAS (.txt) < prev   
Encoding:
GW-BASIC  |  1985-10-24  |  14.0 KB  |  365 lines
  1. 10  CLS:KEY OFF:LOCATE 12,36,0:PRINT"TRUCKER":FOR I=1 TO 2500:NEXT I:GOSUB 5650
  2. 60  COLOR 15,1 : CLS : RNS=VAL(RIGHT$(TIME$,2))
  3. 65  RANDOMIZE RNS
  4. 70  DIM MT(2),MP(2,25),MP$(2,25),MR$(2,25),ZM(2,25),D$(6),NT$(4)
  5. 80  DD$="$$#,###":DC$="$$#,###.##"
  6. 90  NT$(1)="FIRST":NT$(2)="SECOND":NT$(3)="THIRD":NT$(4)="FOURTH"
  7. 92  DS$(0)="MONDAY":DS$(1)="TUESDAY":DS$(2)="WEDNESDAY"
  8. 94  DS$(3)="THURSDAY":DS$(4)="FRIDAY":DS$(5)="SATURDAY":DS$(6)="SUNDAY"
  9. 1000  CLS:XC=190:MF=0:HL=3:HS=7:HR=0:NT=0:GOSUB 2100
  10. 1020  LOCATE 4,8:PRINT"   YOU ARE AT THE LOS ANGELES TRUCKING TERMINAL"
  11. 1030  PRINT"THREE TYPES OF CARGO ARE AVAILABLE:"
  12. 1040  PRINT TAB(5)"1--ORANGES  (HIGHEST PROFIT IF THEY DON'T SPOIL)"
  13. 1050  PRINT TAB(5)"2--FREIGHT FORWARDING  (PENALTY FOR LATE DELIVERY)"
  14. 1060  PRINT TAB(5)"3--U.S. MAIL  (LOWEST RATE, BUT NO HURRY TO ARRIVE)"
  15. 1070  PRINT"THE CARGO IS DUE IN NEW YORK BY 4 PM ON THURSDAY.":INPUT"WHICH TYPE OF CARGO DO YOU WANT";CT
  16. 1080  IF CT<1 OR CT>3 THEN INPUT"PICK A NUMBER:1, 2, 3,";CT:GOTO 1080
  17. 1090  INPUT"HOW MANY POUNDS WILL YOU CARRY (40000 IS THE LEGAL LIMIT)";WL
  18. 1100  IF WL<25000 THEN PRINT"YOU CAN'T MAKE A LIVING ON HALF A LOAD.":GOTO 1090
  19. 1110  PRINT:PRINT TAB(5)"THEY ARE LOADING YOUR TRUCK NOW."
  20. 1120  RESTORE
  21. 1150  FOR RT=0 TO 2:READ NP,MT(RT):FOR I=1 TO NP
  22. 1170  READ MP(RT,I),MP$(RT,I),MR$(RT,I),ZM(RT,I):NEXT I,RT
  23. 1190  TC=10:WF=190:NP=1:TS=1:SL=55:XN=XN+1
  24. 1200  IF WL>50000 THEN WL=50000:PRINT"50,000 POUNDS OF CARGO HAS FILLED YOUR TRAILER!":GOSUB 5650
  25. 1220  HR=HR+1:CLS:GOSUB 2100:LOCATE 4,8:PRINT"   "
  26. 1225  PRINT"YOU PAID $ 190 FOR A NEARLY FULL TANK OF DIESEL.":PRINT
  27. 1230  INPUT"TWO OF YOUR TIRES ARE WORN.  DO YOU WANT REPLACEMENTS";Z$
  28. 1240  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN GOTO 1350
  29. 1250  PRINT"A NEW TIRE COSTS $ 200.  A RETREAD COSTS $ 100.":PRINT TAB(5);
  30. 1260  INPUT"WHICH TYPE DO YOU WANT";Z$:PRINT TAB(5);:Z$=LEFT$(Z$,1)
  31. 1270  INPUT"HOW MANY";T
  32. 1280  IF T=3 THEN IF Z$="N" OR Z$="n" THEN TS=2:T=2:XC=XC+200
  33. 1290  IF T<0 OR T>2 THEN GOTO 1330
  34. 1300  IF T=0 THEN GOTO 1350
  35. 1310  IF Z$="R" OR Z$="r" THEN TC=TC-3*T:XC=XC+100*T:GOTO 1350
  36. 1320  IF Z$="N" OR Z$="n" THEN TC=TC-4*T:XC=XC+200*T:GOTO 1350
  37. 1330  PRINT"I DID NOT UNDERSTAND YOUR ANSWERS.":PRINT"LET'S TRY AGAIN:":PRINT TAB(5);:GOTO 1230
  38. 1350  PRINT:PRINT"YOU MAY CHOOSE THE NORTHERN, MIDDLE, OR SOUTHERN ROUTE."
  39. 1360  INPUT"WHICH ROUTE DO YOU CHOOSE";Z$:Z$=LEFT$(Z$,1)
  40. 1365  IF Z$="N" OR Z$="n" THEN RT=1:RH=4:GOTO 1600
  41. 1370  IF Z$="M" OR Z$="m" THEN RT=0:RH=2:GOTO 1600
  42. 1375  IF Z$="S" OR Z$="s" THEN RT=2:RH=1:GOTO 1600
  43. 1380  PRINT"PLEASE, ANSWER: NORTH, MIDDLE, SOUTH  !":GOTO 1360
  44. 1400  AF=SP ^ 2*CD*CR
  45. 1420  IF AF>RND(0)*1E+07 GOTO 4000
  46. 1430  AF=SQR(MF+100)*TC
  47. 1440  IF AF>RH*2500*RND(0) THEN GOSUB 2600
  48. 1450  IF SP>SL-RH+10 THEN GOSUB 2300
  49. 1460  HR=HR+1:HL=HL+1
  50. 1470  IF SL<40 THEN SL=55
  51. 1480  T=ABS(55-SP):IF T>12 THEN T=12.5
  52. 1490  T1=SP/(4.5-0.2*T)
  53. 1500  WF=WF-T1:IF WF<0 THEN GOSUB 2500
  54. 1510  MF=MF+SP
  55. 1520  IF MF>MT(RT) THEN GOTO 5000
  56. 1530  GOSUB 5650
  57. 1550  CLS:GOSUB 2100
  58. 1560  LOCATE 2,25:PRINT"APPROXIMATE FUEL:";INT(WF-5)+RND(10);TAB(37)"SPEED:";SP
  59. 1570  PRINT TAB(8)"ODOMETER:";MF;TAB(31)"MILES TO GO:";MT(RT)-MF
  60. 1580  PRINT
  61. 1600  IF MP(RT,NP)<=MF THEN GOTO 3100 ELSE PRINT"CRUISIN ON  ";MR$(RT,NP)
  62. 1610  GOSUB 3000:PRINT"YOU ARE FEELING  ";CD$
  63. 1620  GOSUB 2800;PRINT"CURRENT WEATHER:  ";CR$
  64. 1630  NS=NS+1:IF NS>3 THEN GOSUB 1700
  65. 1640  INPUT"HOW FAST DO YOU WISH TO GO";SP
  66. 1650  IF SP<20 THEN PRINT"YOU HAVE TO GO AT LEAST 20--";:GOTO 1640
  67. 1660  IF SP>INT(1.5*SL) THEN SP=INT(1.5*SL):PRINT"YOU CAN ONLY GET THE OLD RIG TO GO ";SP;" MPH ON THIS ROAD."
  68. 1670  GOTO 1400
  69. 1700  REM
  70. 1710  INPUT"TRUCK STOP AHEAD.  DO YOU WANT TO STOP";Z$
  71. 1720  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN NS=1:HL=HL+1:RETURN
  72. 1730  IF LEFT$(Z$,1)<>"Y" AND LEFT$(Z$,1)<>"y" THEN INPUT"MAKE UP YOUR MIND.   YES OR NO";Z$:GOTO 1720
  73. 1735  SLP=0
  74. 1740  T=85+INT(35*RND(0))
  75. 1750  PRINT"DIESEL FUEL COSTS ";T; "CENTS A GALLON."
  76. 1760  INPUT"HOW MANY GALLONS DO YOU WANT";T1
  77. 1770  IF T1>0 THEN STR=CSRLIN:LOCATE STR-1,45:PRINT"PAY ";:PRINT USING"$$###.##";T*T1/100:XC=XC+T*T1/100:WF=WF+T1
  78. 1780  LOCATE STR,24:PRINT"SO FAR, YOU HAVE SPENT ";:PRINT USING DC$;XC
  79. 1790  IF WF> 201 THEN PRINT"YOUR TANK ONLY HOLDS 200 GALLONS --";INT(WF-200);" GALLONS SPILLED !!":WF=200
  80. 1800  IF TS>0 THEN GOTO 1900
  81. 1810  T=200+INT(50*RND(0)):T1=100+INT(70*RND(0))
  82. 1820  PRINT"A NEW TIRE COSTS $ ";T;"    A RETREAD COSTS $ ";T1
  83. 1830  INPUT"DO YOU WANT DO BUY A TIRE";Z$
  84. 1840  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN GOTO 1900
  85. 1850  INPUT"     CHOOSE       :  NEW OR RETREAD";Z$
  86. 1860  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN XC=XC+T:TS=2:GOTO 1900
  87. 1870  IF LEFT$(Z$,1)="R" OR LEFT$(Z$,1)="r" THEN XC=XC+T1:TS=1:GOTO 1900
  88. 1880  PRINT"I DID NOT UNDERSTAND YOUR ANSWERS.":GOTO 1830
  89. 1900  HR=HR+1:NS=0:IF SLP=1 THEN GOTO 2020
  90. 1910  INPUT"DO YOU WANT TO SLEEP";Z$
  91. 1920  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN GOSUB 2100:RETURN
  92. 1930  INPUT"  HOW MANY HOURS OF REST";T
  93. 1940  IF T<1 THEN RETURN
  94. 1950  DH=HR-24*INT(HR/24)
  95. 1960  HR=HR+T:GOSUB 5650:IF CT=1 THEN WF=WF-7*T:IF WF<0 THEN WF=0:GOSUB 2570
  96. 1970  IF DH>21 OR DH<12 THEN T=INT(T/2+0.6):PRINT"THANKS TO THE DAYTIME NOISE, YOU GOT ONLY ";T;" HOURS REAL SLEEP."
  97. 1980  HS=HS+T
  98. 1990  IF T>3 THEN HL=0 ELSE HL=HL/2
  99. 2000  GOSUB 5600
  100. 2010  GOSUB 2100:PRINT"TIME TO HIT THE ROAD AGAIN."
  101. 2015  IF CT=1 THEN PRINT"YOU NOW HAVE ";:PRINT USING"###";WF;:PRINT" GALLONS OF FUEL":INPUT"DO YOU WISH TO BUY MORE";Z$:IF LEFT$(Z$,1)="Y" OR LEFT$(Z$,1)="y" THEN SLP=1:GOTO 1740
  102. 2020  SLP=0:RETURN
  103. 2100  STR=CSRLIN:DH=HR+8
  104. 2120  DT=INT(DH/24):DH=DH-24*DT
  105. 2130  IF DT>6 THEN DT=DT-7:GOTO 2130
  106. 2140  DM$="AM"
  107. 2150  IF DH=12 THEN DM$="NOON":GOTO 2200
  108. 2160  IF DH>12 THEN DH=DH-12:DM$="PM"
  109. 2170  IF DH=0 THEN DH=12 :DM$="MIDNIGHT"
  110. 2200  REM T=PEEK(16416):T1=PEEK(16417)
  111. 2210  LOCATE 1,13:PRINT"DAY:  ";DS$(DT);TAB(37)"TIME :";DH;DM$;"      ";
  112. 2220  REM POKE16416,T:POKE16417,T1
  113. 2230  LOCATE STR,1:RETURN
  114. 2300  REM
  115. 2310  IF(SP-SL+2*RH-5)^2<900*RND(0) THEN RETURN
  116. 2320  PRINT"SMOKEY IS BEHIND YOU WITH HIS LIGHTS ON.  PULL OVER!"
  117. 2340  GOSUB 5650
  118. 2350  NT=NT+1:PRINT"SEE THE JUSTICE OF THE PEACE FOR YOUR  ";NT$(NT);" OFFENSE"
  119. 2360  PRINT"    WAIT";NT;" HOURS FOR YOUR HEARING"
  120. 2370  HR=HR+NT:HL=HL+NT
  121. 2380  IF NT>3 THEN GOTO 2430
  122. 2390  T=INT(NT*RND(5)):T1=5*(INT(RT+NT*RND(4)))
  123. 2400  PRINT"  FINE IS ";:PRINT USING"$### ";T1;:PRINT" PLUS $";T;" FOR EACH MPH OVER THE LIMIT."
  124. 2410  PRINT " PAY ";:PRINT USING DD$;T1+T*(SP-SL):XC=XC+T1+T*(SP-SL)
  125. 2415  FOR I = 1 TO 2500:NEXT I
  126. 2420  GOSUB 5650:GOSUB 5600:RETURN
  127. 2430  PRINT"YOU ARE SENTENCED TO 30 DAYS IN JAIL FOR RECKLESS DRIVING."
  128. 2440  GOSUB 5650
  129. 2450  PRINT"YOUR I.C.C. DRIVER'S LICENSE IS REVOKED  !"
  130. 2460  GOSUB 5500
  131. 2500  T1=T1+WF:WF=0:SP=0
  132. 2520  T=(4.5-0.2*T)*T1:MF=MF+T
  133. 2530  PRINT"AFTER ";T;" MORE MILES, YOU RAN OUT OF FUEL (DUMMY !!)"
  134. 2540  PRINT"  IT COST $200 TO GET A BARREL OF DIESEL DELIVERED."
  135. 2550  WF=55:T1=RND(5):HR=HR+T1:XC=XC+200:HL=HL+T1
  136. 2560  PRINT TAB(5)"  YOU ALSO WASTED ";T1;" HOURS BY YOUR CARELESSNESS."
  137. 2570  IF CT=1 THEN CX=CX+RND(3):PRINT"SITTING WITH THE REFER UNIT OFF IS DAMAGING THE ORANGES."
  138. 2580  FOR I=1 TO 800:NEXT I
  139. 2590  RETURN
  140. 2600  GOSUB 5600:PRINT"YOU JUST BLEW A TIRE !!"
  141. 2630  IF TS=0 THEN 2710
  142. 2640  TC=TC-2*TS:TS=0
  143. 2650  T=INT(RND(2))+1:IF T<2 THEN T$="OUTSIDE" ELSE T$="INSIDE"
  144. 2660  PRINT"IT TOOK ";T;" HOURS TO CHANGE THE ";T$;" TIRE.":HR=HR+T:HL=HL+T
  145. 2670  GOSUB 5650:RETURN
  146. 2710  PRINT"SINCE YOUR SPARE HAS ALREADY BEEN USED, YOU HAVE TO CALL A TOW TRUCK FROM TOWN TO DELIVER A NEW TIRE TO YOU."
  147. 2720  PRINT"  THIS SERVICE COST $400 AND TOOK 4 HOURS."
  148. 2730  HR=HR+4:HL=HL+4:XC=XC+400
  149. 2740  GOSUB 5650:RETURN
  150. 2800  REM
  151. 2810  AF=(3000+MF)*RND(0):ON(RT+1) GOTO 2870,2820,2910
  152. 2820  IF AF<3300 AND CR<>50 THEN GOTO 2960
  153. 2830  IF AF>4800 THEN GOTO 2965
  154. 2840  IF AF>4600 THEN GOTO 2970
  155. 2850  IF AF>3800 THEN GOTO 2975
  156. 2860  GOTO 2985
  157. 2870  IF AF<3400 AND CR<>50 THEN GOTO 2960
  158. 2880  IF AF>4900 THEN GOTO 2965
  159. 2890  IF AF>4700 THEN GOTO 2970
  160. 2900  IF AF>4200 THEN IF RND(3)=1 THEN GOTO 2975 ELSE GOTO 2980
  161. 2905  GOTO 2985
  162. 2910  IF AF<4000 AND CR<>50 THEN GOTO 2960
  163. 2920  IF AF>5700 THEN GOTO 2965
  164. 2930  IF AF>5500 THEN GOTO 2970
  165. 2940  IF AF>4400 THEN GOTO 2980
  166. 2950  GOTO 2985
  167. 2960  CR=1:CR$="CLEAR & DRY":RETURN
  168. 2965  CR=50:CR$="B-L-I-Z-Z-A-R-D  !!":RETURN
  169. 2970  CR=10:CR$="FOG -- LIMITED VISIBILITY":RETURN
  170. 2975  CR=5:CR$="LIGHT SNOW":RETURN
  171. 2980  CR=5:CR$="RAIN":RETURN
  172. 2985  CR=3:CR$="CLEAR, BUT ROADWAY IS WET":RETURN
  173. 3000  REM**
  174. 3010  IF HL>19 OR HR/HS>4 THEN CD=100:CD$="  ..E.X.H.A.U.S.T.E.D..":RETURN
  175. 3020  IF HL<4 AND CSNG(HR/HS)<2.3 THEN CD=1:CD$="RESTED AND REARING TO GO.":RETURN
  176. 3030  IF HL<8 AND CSNG(HR/HS)<2.5 THEN CD=2:CD$="FINE":RETURN
  177. 3040  IF HL<12 AND HR/HS <=3 THEN CD=4:CD$="B O R E D":RETURN
  178. 3050  IF HL<16 AND HR/HS <=3 THEN CD=8:CD$="T I R E D  !!":RETURN
  179. 3060  CD=25:CD$="FATIGUED. . .yOU'RE GETTING SLEEPY":RETURN
  180. 3100  REM
  181. 3110  PRINT"YOU HAVE JUST PASSED ";MP$(RT,NP)
  182. 3120  ZH=ZM(RT,NP):SL=55
  183. 3130  ON INT(ZH) GOSUB 3210,3310,3360,3410,3500,3710,3860
  184. 3140  NP=NP+1:IF INT(ZH)=8 THEN 5000 ELSE 1600
  185. 3210  PRINT"TIME ZONE CHANGES -- SET CLOCK AHEAD ONE HOUR"
  186. 3220  HR=HR+1:GOSUB 2100
  187. 3230  RETURN
  188. 3310  T=100*(ZH-INT(ZH))
  189. 3320  PRINT"STOP!    PAY TOLL OF ";:PRINT USING"$##.##";T
  190. 3330  XC=XC+T
  191. 3340  RETURN
  192. 3360  IF RND(0)<ZH-INT(ZH) THEN RETURN
  193. 3370  PRINT"CONSTRUCTION AHEAD  !!":FOR I=1 TO 500:NEXT I
  194. 3380  PRINT"SLOW DOWN -- SPEED LIMIT 35 MPH":SL=35
  195. 3390  RETURN
  196. 3410  IF RND(0)<ZH-INT(ZH) THEN RETURN
  197. 3420  T=SP+RND(5)-2
  198. 3430  PRINT"YOU WERE JUST CLOCKED BY RADAR AT ";T;" MPH"
  199. 3440  IF T>SL+3 THEN GOSUB 2320 ELSE PRINT"   NO TICKET THIS TIME."
  200. 3450  RETURN
  201. 3500  IF ZH=INT(ZH) THEN IF RND(0)<0.5 THEN GOTO 3520 ELSE RETURN
  202. 3510  IF RND(0)<ZH-INT(ZH) THEN RETURN
  203. 3520  PRINT"WEIGH STATION OPEN -- TRUCKS MUST STOP":GOSUB 5650
  204. 3530  PRINT"SCALE WEIGHS TRUCK WITH CARGO, FUEL & DRIVER:";
  205. 3540  T=19000+WL+7*WF+25*RND(10)
  206. 3550  PRINT USING"##,###";T;:PRINT" POUNDS."
  207. 3560  T=INT(T-60000)
  208. 3570  IF T<1 THEN PRINT"    YOU'RE O.K.":RETURN
  209. 3580  IF ZH=5 THEN GOTO 3630
  210. 3590  T1=RND(4)+2:PRINT"  OVERWEIGHT FINE IS $200 PLUS ";T1;" CENTS/POUND"
  211. 3600  XC=XC+200+(T*T1)/100
  212. 3610  PRINT"PAY FINE OF ";:PRINT USINGDC$;200+(T*T1)/100
  213. 3620  RETURN
  214. 3630  REM
  215. 3640  PRINT"YOU ARE NOT ALLOWED TO ENTER LOUSIANA WITH THAT LOAD."
  216. 3650  PRINT"TAKE A 200 MILE DETOUR THROUGH ARKANSAS WITH 45 MPH LIMIT."
  217. 3660  SL=45:MR$(RT,NP)="ARKANSAS COUNTY ROADS"
  218. 3670  FOR I=12 TO 25:MP(RT,I)=MP(RT,I)+200:NEXT I
  219. 3680  MT(RT)=MT(RT)+200
  220. 3690  RETURN
  221. 3710  IF RND(0)<ZH-INT(ZH) THEN RETURN
  222. 3720  T=INT(RND(6))+1
  223. 3730  PRINT"A ROCK SLIDE HAS BLOCKED THE ALLEGHANY TUNNEL ENTRANCE"
  224. 3740  PRINT"THE HIGHWAY DEPARTMENT WILL HAVE IT CLEARED IN ";T;" HOURS"
  225. 3750  HR=HR+T:GOSUB 5650:IF CT=1 THEN WF=WF-7*T:IF WF<=1 THEN GOSUB 3820
  226. 3760  IF T>1 THEN T1=INT(T/2+0.5) ELSE T1=0
  227. 3770  IF T>3 THEN HL=0 ELSE IF T1>0 THEN HL=HL/2
  228. 3780  HS=HS+T1
  229. 3790  PRINT"WHILE WAITING, YOU GOT ";T1;" HOURS OF SLEEP"
  230. 3800  GOSUB 2100 :RETURN
  231. 3820  PRINT"YOU RAN OUT OF GAS WHILE WAITING":T=0:GOSUB 2540
  232. 3830  RETURN
  233. 3860  IF CT>1 THEN RETURN
  234. 3870  IF RND(0)<ZH-INT(ZH) THEN RETURN
  235. 3880  PRINT"THE TRAILER REFRIGERATION UNIT HAS FAILED ENDANGERING THE CARGO"
  236. 3890  PRINT"REPAIRS TOOK 2 HOURS AND COST $100"
  237. 3900  CX=CX+RND(4):HR=HR+2:HL=HL+2:XC=XC+100
  238. 3910  GOSUB 2100:GOSUB 5650
  239. 3920  RETURN
  240. 4000  GOSUB 5600
  241. 4020  FOR I=1 TO 12:CLS:FOR J=1 TO 60:NEXT J
  242. 4040  LOCATE 12,32:PRINT "C  R  A  S  H   !!"
  243. 4050  FOR J=1 TO 60:NEXT J,I:PRINT
  244. 4070  IF CD=100 OR (CD=25 AND SP<65) THEN PRINT"YOU FELL ASLEEP AT THE WHEEL":GOTO 4130
  245. 4080  IF CR=50 THEN PRINT"YOU DROVE OFF THE ROAD  INTO     A SNOW FILLED DITCH":GOTO 4130
  246. 4090  IF CR=10 THEN PRINT"YOU REAR-ENDED A PICK-UP WITH NO TAIL LIGHTS":GOTO 4130
  247. 4100  IF SP>65 THEN PRINT"SPEED KILLS  !":GOTO 4130
  248. 4110  IF CR>2 THEN PRINT"YOU HIT A SLICK SPOT":PRINT"AND SKIDDED OFF THE ROAD.":GOTO 4130
  249. 4120  PRINT"A DRUNK DRIVER RAMMED YOUR RIG":PRINT TAB(8)"TOUGH LUCK  !"
  250. 4130  PRINT:GOSUB 5650
  251. 4140  PRINT"YOU LOSE YOUR TRUCK & PROFITS":PRINT
  252. 4150  PRINT:INPUT"DO YOU WANT TO START OVER";Z$
  253. 4160  IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN CLS:END
  254. 4170  XP=0:CLS:GOTO 1000
  255. 5000  FOR I=1 TO 12:CLS:FOR K=1 TO 100:NEXT K
  256. 5030  LOCATE 5,36:PRINT "WELCOME":LOCATE 7,38:PRINT"TO":LOCATE 9,35:PRINT"NEW YORK"
  257. 5040  FOR J=1 TO 60:NEXT J,I
  258. 5050  FOR I=1 TO 250 :NEXT I:CLS
  259. 5100  GOSUB 2100:LOCATE 2,20:PRINT"  "
  260. 5110  T=HR-INT(HR/24):IF T<10 OR T>21 THEN 5140
  261. 5120  PRINT"THE WAREHOUSE IS CLOSED FOR THE NIGHT.  COME BACK TOMORROW."
  262. 5130  T=24-T:HR=HR+T:GOSUB 5650:GOSUB 2100
  263. 5140  PRINT:T=INT(HR/24):T1=HR-24*T
  264. 5150  PRINT"YOU COMPLETED THE TRIP IN ";T;" DAYS";
  265. 5160  IF T1>1 THEN PRINT" & ";T1;" HOURS." ELSE PRINT
  266. 5170  PRINT"  TRIP EXPENSES TOTAL ";:PRINT USING DC$;XC
  267. 5180  T1=85*T+85:PRINT"  TRUCK PAYMENTS, INSURANCE & TAXES COST ";:PRINT USING DD$;T1
  268. 5190  XC=XC+T1:PRINT
  269. 5200  ON CT GOTO 5220,5310,5360
  270. 5220  T1=(T-4)*RND(3):IF T1>0 THEN CX=CX+T1
  271. 5230  IF CX>6 THEN PRINT"YOUR ORANGES HAVE SPOILED.  HAUL THEM TO THE DUMP!":XT=-50:GOTO 5400
  272. 5240  PRINT"COLLECT SIX-AND-A-HALF CENTS PER POUND FOR GOOD ORANGES."
  273. 5250  XT=0.065*WL:PRINT"  TOTAL FOR THE LOAD:  ";:PRINT USING DC$;XT
  274. 5260  IF CX<1 THEN 5400
  275. 5270  PRINT"  PART OF THE LOAD IS DAMAGED.  SUBTRACT ";:PRINT USING"##";5*CX;:PRINT" % ."
  276. 5280  XT=XT-XT*CX/20:PRINT"  NET PAYMENT IS ";:PRINT USING DC$;XT
  277. 5290  GOTO 5400
  278. 5310  XT=0.05*WL:PRINT"  COLLECT FIVE CENTS A POUND FOR FREIGHT."
  279. 5320  PRINT"  TOTAL FOR LOAD= ";:PRINT USING DC$;XT
  280. 5330  IF HR<95 THEN 5400
  281. 5340  CX=2:PRINT"  YOU ARE LATE !! SUBTRACT TEN PERCENT PENALTY.":GOTO 5290
  282. 5360  PRINT"POSTMASTER PAYS 4.75 CENTS PER POUND ON DELIVERY.":XT=0.0475*WL:CX=0:GOTO 5290
  283. 5400  PRINT:XT=XT-XC:XP=XP+XT:IF XT<0 THEN GOTO 5470
  284. 5410  PRINT"YOUR NET PROFIT THIS TRIP WAS ";:PRINT USINGDC$;XT
  285. 5420  IF XT>1000 THEN PRINT"  GOOD WORK  !!"
  286. 5430  IF XN>1 THEN PRINT"YOUR AVERAGE PROFIT HAS BEEN";:PRINT USING DC$;XP/XN
  287. 5440  IF XT<200 OR XP/XN<250 THEN PRINT"YOU'D MAKE MORE MONEY WASHING DISHES!"
  288. 5450  PRINT:PRINT:INPUT"DO YOU WANT TO MAKE ANOTHER TRIP";Z$
  289. 5460  IF LEFT$(Z$,1)<>"N" AND LEFT$(Z$,1)<>"n" THEN GOTO 1000 ELSE CLS:END
  290. 5470  PRINT"BAD TRIP. . . YOU LOST";:PRINT USING DC$;ABS(XT)
  291. 5480  IF XP>=0 THEN GOTO 5430
  292. 5490  PRINT"YOU ARE BANKRUPT!!!"
  293. 5500  GOSUB 5650:GOSUB 5650
  294. 5520  PRINT:PRINT"YOUR RIG HAS BEEN REPOSSESSED."
  295. 5530  PRINT:GOTO 5450
  296. 5600  FOR I=1 TO 12:FOR J=1 TO 3:NEXT J,I:RETURN
  297. 5650  FOR I=1 TO 1800:NEXT I:RETURN
  298. 9030  DATA 21,2850
  299. 9040  DATA 90,BARSTOW,I-15 IN CALIFORNIA,7.80
  300. 9050  DATA 225,NEEDLES,I-40 IN CALIFORNIA,1
  301. 9060  DATA 440,FLAGSTAFF,I-40 IN ARIZONA,3.65
  302. 9070  DATA 620,GALLUP,I-40 IN ARIZONA,5.5
  303. 9080  DATA 760,ALBUQUERQUE,I-40 IN NEW MEXICO,3.35
  304. 9090  DATA 930,TUCUMCARI,I-40 IN NEW MEXICO,1
  305. 9100  DATA 1040,AMARILLO,I-40 IN TEXAS,7.80
  306. 9110  DATA 1155,OKLAHOMA BORDER,I-40 IN TEXAS,5.5
  307. 9120  DATA 1305,OKLAHOMA CITY,I-40 IN OKLAHOMA,2.65
  308. 9130  DATA 1530,MISSOURI BORDER,OKLAHOMA TURNPIKE,2.40
  309. 9140  DATA 1815,ST. LOUIS,I-44 IN MISSOURI,0
  310. 9150  DATA 1980,TERRE HAUTE,I-70 IN ILLINOIS,5.5
  311. 9160  DATA 2050,INDIANAPOLIS,I-70 IN INDIANA,0
  312. 9170  DATA 2115,OHIO BORDER,I-70 IN INDIANA,1
  313. 9180  DATA 2220,COLUMBUS,I-70 IN OHIO,5.5
  314. 9190  DATA 2350,WHEELING WEST VIRGINIA,I-70 IN OHIO,5.25
  315. 9200  DATA 2410,NEW STANTON,I-70 IN PENNSYLVANIA,6.75
  316. 9210  DATA 2570,HARRISBURG,PENNSYLVANIA TURNPIKE,3.75
  317. 9220  DATA 2760,NEW JERSEY BORDER,PENNSYLVANIA TURNPIKE,2.95
  318. 9230  DATA 2840,HOLLAND TUNNEL,I-70 IN NEW JERSEY,2.40
  319. 9240  DATA 9999,NEW YORK,NEW YORK STREETS,0
  320. 9255  DATA 18,2710
  321. 9260  DATA 90,BARSTOW,I-15 IN CALIFORNIA,7.80
  322. 9270  DATA 245,LAS VEGAS,I-15 IN CALIFORNIA,1
  323. 9280  DATA 365, UTAH BORDER,I-15 IN ARIZONA,0
  324. 9290  DATA 500,END OF INTERSTATE,I-15 IN UTAH,3.20
  325. 9300   DATA 555,SALINA, US-89 IN UTAH,4.50
  326. 9310  DATA 760,GRAND JUNCTION,I-70 IN UTAH,5.40
  327. 9320  DATA 1010, DENVER,I-70 IN COLORADO,3.75
  328. 9330  DATA 1190,NEBRASKA BORDER,I-76 IN COLORADO,1
  329. 9340  DATA 1450, OMAHA,I-80 IN NEBRASKA,5.50
  330. 9350  DATA 1590,DES MOINES, I-80 IN IOWA,4.75
  331. 9360  DATA 1750,ILLINOIS BORDER,I-80 IN IOWA,5.6
  332. 9370  DATA 1910,GARY,I-80 IN ILLINOIS,2.50
  333. 9380  DATA 2050,OHIO BORDER, INDIANA TURNPIKE,2.45
  334. 9390  DATA 2215,CLEVELAND,OHIO TURNPIKE,2.80
  335. 9400  DATA 2280,PENSYLVANIA BORDER,I-80 IN OHIO,4.16
  336. 9410  DATA 2615,EAST STROUDSBERG,I-80 IN PENSYLVANIA,3.33
  337. 9420  DATA 2675,WASHINGTON BRIDGE,I-80 IN NEW JERSEY,2.20
  338. 9430  DATA 9999, NEW YORK, CITY STREETS,0
  339. 9450  DATA 25,3120
  340. 9460  DATA 75, PALM SPRINGS,I-10 IN CALIFORNIA,0
  341. 9470  DATA 225,BLYTHE,I-10 IN CALIFORNIA,0
  342. 9480  DATA 375, PHOENIX,I-10 IN ARIZONA,0
  343. 9490  DATA 495, TUCSON,I-10 IN ARIZONA,7.9
  344. 9500  DATA 650,LORDSBURG,I-10 IN ARIZONA,5.75
  345. 9510  DATA 795, EL PASO,I-10 IN NEW MEXICO,0
  346. 9520  DATA 965,PECOS,I-10 IN TEXAS,1
  347. 9530  DATA 1080,ODESSA,I-20 IN TEXAS,0
  348. 9540  DATA 1250, ABILENE,I-20 IN TEXAS,3.80
  349. 9550  DATA 1439,DALLAS,I-20 IN TEXAS,0
  350. 9560  DATA 1610,LOUISIANA BORDER,I-20 IN TEXAS,5.00
  351. 9570  DATA 1785,VICKSBURG,I-20 IN LOUISIANA,0
  352. 9580  DATA 1965,ALABAMA BORDER,I-20 IN MISSISSIPPI,1
  353. 9590  DATA 2100,BIRMINGHAM,I-20 IN ALABAMA,4.25
  354. 9600  DATA 2200,GEORGIA BORDER,I-20 IN ALABAMA,0
  355. 9610  DATA 2255,ATLANTA,I-20 IN GEORGIA,0
  356. 9620  DATA 2320,CAROLINA BORDER,I-85 IN GEORGIA,5.75
  357. 9630  DATA 2565,GREENSBORO,I-85 IN NORTH CAROLINA,3.80
  358. 9640  DATA 2680,VIRGINA BORDER,I-85 IN NORTH CAROLINA,7.85
  359. 9650  DATA 2775,RICHMOND,I-85 IN VIRGINA,0
  360. 9660  DATA 2880,WASHINGTON D.C.,I-95 IN VIRGINA,0
  361. 9670  DATA 2920,BALTIMORE,I-95 IN MARYLAND,2.30
  362. 9680  DATA 2990,NEW JERSEY BORDER,I-95 IN DELAWARE,2.25
  363. 9690  DATA 3110,HOLLAND TUNNEL,NEW JERSEY TURNPIKE,2.40
  364. 9700  DATA 9999,NEW YORK, CITY STREETS,0
  365.